WinForms

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

gmlogic — Mon, 18 Sep 2006 16:23:18 GMT

Σας ευχαριστώ όλους για τη βοήθεια :)

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

Dimitris Papadimitriou — Wed, 13 Sep 2006 21:04:33 GMT

Επίσης, αν χρησιμοποιείς την getchanges, ενημερώνεις, και μετά κάνεις merge στο αρχικό dataset, πρέπει να έχεις υπόψη σου κάποια πράγματα που αναφέρονται εδώ: http://msdn2.microsoft.com/en-us/library/ks9f57t0.aspx

Δες το σημείο που μιλάει για "Merging New Identity Values".

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

Dimitris Papadimitriou — Wed, 13 Sep 2006 21:00:53 GMT

1) δημιουργώ commandbuilder

2) παίρνω insert command (σε προσωρινή μεταβλητή, όχι στον adapter)

3) τροποποιώ insert command : προσθέτω στο τέλος του command text ένα SELECT MyIdentityColumn, Col1, Col2 .... FROM MyTable WHERE MyIdentityColumn=SCOPE_IDENTITY()

4) αλλάζω το UpdatedRowSource του insert command σε Both

5) εκτελώ το commandBuilder.RefreshSchema

6) θέτω το insert command στον adapter

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

gmlogic — Wed, 13 Sep 2006 00:58:27 GMT

Ok Μάνο ευχαριστώ

Μήπως θα μπορούσε ο Δημήτρης να μας στείλει ένα παραδειγματάκι.

Γιατί λέει οτι του δουλεύει με το RefreshSchema σε ποιά σημεία το βάζη?

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

KelMan — Wed, 13 Sep 2006 00:12:40 GMT

H DbCommandBuilder είναι abstract base class που σημαίνει ότι δεν μπορείς να την χρησιμοποιήσεις απ'ευθείας, δηλαδή δεν μπορείς να πεις

Dim command_builder As New DbCommandBuilder(...)

και γι αυτόν το λόγο δεν έχει την clone μέθοδο.

Σχετικά με το RefreshSchema, στο MSDN λέει:

The DbCommandBuilder also uses the Connection, CommandTimeout, and Transaction properties referenced by the SelectCommand. The user should call RefreshSchema if any of these properties are modified, or if the SelectCommand itself is replaced. Otherwise the InsertCommand, UpdateCommand, and DeleteCommand properties retain their previous values.

Πραγματικά, δεν μπορώ να φανταστώ το πως μπορεί να βοηθήσει το RefreshSchema από την στιγμή που αλλάζεις το CommandText property του InsertCommand.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

gmlogic — Tue, 12 Sep 2006 18:52:41 GMT

Ok Μάνο το κατάλαβα και μου δούλεψε.

Μόνο υπάρχει ένα μικρό πρόβλημα

Όταν δίνω DataAdapterCategories.InsertCommand = CommandBuilderCategories.GetInsertCommand.Clone

γιά να δουλέψει επειδή όπως επισήμανες και συ αν δεν δώσω clone δεν κρατάει το

SELECT @@IDENTITY AS ColumnI

Επειδή χρησιμοποιώ το παραδειγμά σου

Dim command_builder As DbCommandBuilder = dataFactory.CreateCommandBuilder()

το clone δεν υπάρχει

Μήπως το RefreshSchema που λέει ο Δημήτρης πέζει?

Πάντως με το

Dim CommandBuilderCategories As New SqlCommandBuilder(DataAdapterCategories)

Πέζει μιά χαρά

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

KelMan — Tue, 12 Sep 2006 03:21:56 GMT

Όταν γίνεται το Update από τον DataAdapter η νέα τιμή του ID μπαίνει στην θέση της παλιάς μέσα στο DataRow. Κοίταξε τον κώδικα step-by-step, την δεύτερη φορά που τρέχει η PrintRows μπορείς να διαβάσεις την τιμή και να την περάσεις σε μεταβλητή.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

gmlogic — Mon, 11 Sep 2006 21:40:39 GMT

Μου έμεινε ένα κενό για την δεύτερη λύση.

Πώς πέρνω το ColumnID σε μιά μεταβλητή?

Καί πάλι σας ευχαριστώ

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

Dimitris Papadimitriou — Mon, 11 Sep 2006 16:32:13 GMT

KelMan wrote:

Δεν ξέρω τα inner workings του DataAdapter, ενδεχομένως να ξανακαλεί κάποια στιγμή την GetInsertCommand. Εν κατακλείδει, το πρόβλημα τελικά λύνεται αν πούμε

Και εγώ δεν τα ξέρω, αλλά επειδή όντως κάτι συμβαίνει εκεί, το refreshschema το λύνει. Εγώ το βάζω αφού έχω πάρει το insert command από τον commandbuilder και το έχω τροποποιήσει και πριν το θέσω στον adapter.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

KelMan — Mon, 11 Sep 2006 08:42:35 GMT

OK, ανακάλυψα τι φταίει στο δεύτερο σενάριο και τώρα μπορώ να πάω για ύπνο...

Λοιπον, οι δύο βασικές εντολές είναι:

DataAdapterCategories.InsertCommand = CommandBuilderCategories.GetInsertCommand
DataAdapterCategories.InsertCommand.CommandText &= "; SELECT @@IDENTITY AS ColumnID"

Από τον Profiler είδα ότι όταν ο DataAdapter στέλνει την InsertCommand, o SQL Server λαμβάνει προς εκτέλεση το παρακάτω:

exec sp_executesql N'INSERT INTO [DataBuilderDemo] ([Column1]) VALUES (@p1)',N'@p1 nvarchar(5)',@p1=N'New Row'

που σημαίνει ότι άσχετα αν εμείς προσθέτουμε το "; SELECT @@IDENTITY AS ColumnID" στο τέλος του CommandText property, αυτό αγνοείται! Το κόλπο είναι να πάρουμε όλο το Command object μέσω του CommandBuilder (γιατί μας ενδιαφέρει το CommandText αλλά και το Parameters collection) αλλά να μην διατηρήσουμε το reference στo CommandBuilder ώστε μετά να μπορούμε να το αλλάξουμε. Δεν ξέρω τα inner workings του DataAdapter, ενδεχομένως να ξανακαλεί κάποια στιγμή την GetInsertCommand. Εν κατακλείδει, το πρόβλημα τελικά λύνεται αν πούμε

DataAdapterCategories.InsertCommand = CommandBuilderCategories.GetInsertCommand.Clone
...

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

KelMan — Mon, 11 Sep 2006 04:20:50 GMT

To δοκίμασες; Που ακριβώς να πάει το RefreshSchema; Γιατί αν θυμάμαι καλά, το RefreshSchema απλά καθαρίζει τα Commands του CommandBuilder.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

Dimitris Papadimitriou — Mon, 11 Sep 2006 04:06:42 GMT

Το βρήκα! Η 2η λύση είναι εφικτή!

Πρέπει να μπει κάπου εκεί και το CommandBuilderCategories.RefreshSchema()

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

KelMan — Mon, 11 Sep 2006 03:35:04 GMT

Λοιπόν, το κοίταξα το πρόβλημα κι έγραψα λίγο κώδικα για να δοκιμάσω στην πράξη αυτά που θεωρητικά είπαμε. Ανακεφαλαιώνοντας, έχουμε και λέμε:

Υπάρχουν τρεις τρόποι για να κάνεις αυτό που θέλεις. Ας ξεκινήσουμε από τον πρώτο που είναι να χρησιμοποιήσεις το RowUpdated event του DataAdapter και την στιγμή που γράφεται κάθε εγγραφή να στέλνεις ένα Query που να ρωτάς το νέο ID.

Σε όλα τα παραδείγματα, υποτίθεται ότι δουλεύουμε σε έναν πίνακα στη Northwind που τον έχω φτιάξει με αυτήν την εντολή

CREATE TABLE DataBuilderDemo(ColumnID int identity NOT NULL PRIMARY KEY, Column1 nvarchar(16) NOT NULL)

O κώδικας στην φόρμα έχει ως εξής:

    Dim ConnectionNorthwind As New SqlConnection("Data Source=.;Initial Catalog=Northwind;Integrated Security=True")
    Dim DataAdapterCategories As New SqlDataAdapter("SELECT ColumnID, Column1 FROM DataBuilderDemo", ConnectionNorthwind)
    Dim CommandBuilderCategories As New SqlCommandBuilder(DataAdapterCategories)
    Dim DataTableCategories As New DataTable
    Dim CommandRefresh As New SqlCommand("SELECT @@IDENTITY", ConnectionNorthwind)

    Private Sub CreateInsertCommandButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CreateInsertCommandButton.Click
        DataAdapterCategories.InsertCommand = CommandBuilderCategories.GetInsertCommand
        AddHandler DataAdapterCategories.RowUpdated, AddressOf RowUpdatedHandler
    End Sub

    Private Sub FillTableButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles FillTableButton.Click
        DataAdapterCategories.Fill(DataTableCategories)
    End Sub

    Private Sub AddNewRowButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles AddNewRowButton.Click
        Dim RowNew As DataRow
        RowNew = DataTableCategories.NewRow
        RowNew.Item(0) = 0
        RowNew.Item(1) = "New Row"
        DataTableCategories.Rows.Add(RowNew)

        PrintRows("Rows before update:")
    End Sub

    Private Sub UpdateButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles UpdateButton.Click
        Try
            DataAdapterCategories.Update(DataTableCategories)
        Catch ex As Exception
            Console.WriteLine(ex.Message)
        End Try

        PrintRows("Rows after update:")
    End Sub

    Private Sub PrintRows(ByVal message As String)
        Console.WriteLine(message)

        For Each row As DataRow In DataTableCategories.Rows
            Console.WriteLine(String.Format("    {0}, {1}", row.Item(0), row.Item(1)))
        Next row

        Console.WriteLine()
    End Sub

    Private Sub RowUpdatedHandler(ByVal sender As Object, ByVal e As SqlRowUpdatedEventArgs)
        If e.Status = UpdateStatus.[Continue] AndAlso (e.StatementType = StatementType.Insert) Then
            e.Row("ColumnID") = CInt(CommandRefresh.ExecuteScalar)
            e.Row.AcceptChanges()
        End If
    End Sub

Προσοχή χρειάζεται στα εξής σημεία: Δεν μπορούμε να χρησιμοποιήσουμε SCOPE_IDENTITY() αντί για @@IDENTITY γιατί στη RowUpdatedHandler, κάθε φορά που τρέχουμε το CommandRefresh, δημιουργείται νέο connection και το SCOPE_IDENTITY() επιστρέφει null. Επίσης, αυτή η τεχνική δουλεύει και σε Access.

Η δεύτερη τεχνική είναι να αλλάξεις το InsertCommand που σου δίνει ο CommandBuilder έτσι ώστε να έχεις ένα Batched Query. Στη νέα έκδοση των παραπάνω, καταργείται η ρουτίνα RowUpdatedHandler, και το περιεχόμενο της CreateInsertCommandButton_Click αλλάζει σε:

    Private Sub CreateInsertCommandButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CreateInsertCommandButton.Click
        DataAdapterCategories.InsertCommand = CommandBuilderCategories.GetInsertCommand
        DataAdapterCategories.InsertCommand.CommandText &= "; SELECT @@IDENTITY AS ColumnID"
        DataAdapterCategories.InsertCommand.UpdatedRowSource = UpdateRowSource.FirstReturnedRecord
    End Sub

Όμως φρούδες οι ελπίδες... Το παραπάνω δεν δουλεύει αν και θα έπρεπε! Λέω "αν και θα έπρεπε" γιατί αν αντί γι αυτό, γράψουμε

    Private Sub CreateInsertCommandButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CreateInsertCommandButton.Click
        Dim InsertCommand As SqlCommand
        Dim strSQL As String
        strSQL = "INSERT INTO DataBuilderDemo (Column1) VALUES (@Column1); SELECT SCOPE_IDENTITY() AS ColumnID"
        InsertCommand = New SqlCommand(strSQL, ConnectionNorthwind)
        InsertCommand.Parameters.Add("@Column1", SqlDbType.NVarChar, 16, "Column1")
        InsertCommand.UpdatedRowSource = UpdateRowSource.FirstReturnedRecord
        DataAdapterCategories.InsertCommand = InsertCommand
    End Sub

δηλαδή κατασκευάσουμε χειροκίνητα την InsertCommand, τότε παίζει! Απλά δεν του κάνει η InsertCommand που γυρίζει ο CommandBuilder, ακόμα κι αν προσθέσει κανείς στο τέλος το "; SELECT SCOPE_IDENTITY() AS ColumnID". Βασικά, έκανα πολλές δοκιμές αλλά δεν βρήκα καμιά ειδοποιό διαφορά ανάμεσα στα δύο Commands ώστε να καταλάβω τι δεν πάει καλά με το command που παράγει το CommandBuilder. Όποιος έχει όρεξη ας το ψάξει περισσότερο να μας πει.

Υπάρχει και μία τρίτη τεχνική που είναι να χρησιμοποιήσεις stored procedure η οποία θα επιστρέφει ως output το νέο ID.

CREATE PROCEDURE spInsertDataBuilderDemo
(@ColumnID int OUTPUT,
@Column1 nvarchar(16))
AS
INSERT INTO tblAutoIncrementTest(Column1) VALUES (@Column1)
SELECT @ColumnID = SCOPE_IDENTITY()

Και αντίστοιχα, η CreateInsertCommandButton_Click γίνεται κάπως έτσι:

    Private Sub CreateInsertCommandButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles CreateInsertCommandButton.Click
        Dim InsertCommand As SqlCommand
        Dim strSQL As String
        Dim param As SqlParameter
        strSQL = "spAutoIncrementTestInsert"
        InsertCommand = New SqlCommand(strSQL, ConnectionNorthwind)
        param = InsertCommand.Parameters.Add("@ColumnID", SqlDbType.Int, 0, "ColumnID")
        param.Direction = ParameterDirection.Output
        InsertCommand.Parameters.Add("@Column1", SqlDbType.NVarChar, 16, "Column1")
        InsertCommand.CommandType = CommandType.StoredProcedure
        InsertCommand.UpdatedRowSource = UpdateRowSource.OutputParameters
        DataAdapterCategories.InsertCommand = InsertCommand
    End Sub

Από τις τρεις λύσεις, εφόσον θέλεις απαραιτήτως να χρησιμοποιήσεις CommandBuilder ουσιαστικά σου κάνει μόνο η πρώτη. Θα σου πρότεινα να επανεξετάσεις το κατά πόσο είναι εφικτό να μην χρησιμοποιήσεις τον CommandBuilder και να περάσεις στην δεύτερη ή ακόμα καλύτερα την τρίτη λύση που έχει καλύτερο performance. Προσωπικά, ποτέ δεν τον έχω χρησιμοποιήσει και τώρα βλέπω πόσο δίκιο έχουν όλοι αυτοί που έγραφαν στα blogs και τα βιβλία τους ότι είναι μόνο για quick & dirty και όχι production κώδικα.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

Dimitris Papadimitriou — Sun, 10 Sep 2006 23:52:58 GMT

gmlogic wrote:
Λοιπόν !!!!

Ποιό πάνω έχω τον κώδικα που ανάλογα το DataRowState φτιάχνει

ο command_builder τα sql querys

Μπορώ να πάρω το ID μετά το

da_Sql.InsertCommand = command_builder.GetInsertCommand()

ή δεν μπορώ?

Ή πρέπει να αλλάξω τον κωδικά μου και να τα κάνω χειροκίνητα

ή πρέπει να γυρίσω τα queries σε store procedures ή ......

ή γιατί πρέπει να μιλάμε για MSSQL2005

Δέν ξερω :)

Όπως μς χαρά θα συμβούλευα ένα με λιγώτερη γνώση από μένα

έτσι θέλω και εγώ να μάθω από κάποιον που ξέρει ποιό πολά από μένα

γιατί σίγουρα κάποιος ξέρει ποιό πολλά από μένα ......

Γιώργος Μ.

Εγώ το κάνω πολύ καιρό αυτό και με generic κώδικα, όπως περίπου αυτόν που έχεις και εσύ. CommandBuilder και δημιουργία του select statement με loop. Λειτουργεί πολύ καλά τόσο σε sql2000 όσο και σε sql2005.

Απ: Πως θα πάρω το τελευταίο Id πίνακα?

gmlogic — Sun, 10 Sep 2006 22:51:39 GMT

Λοιπόν !!!!

Ποιό πάνω έχω τον κώδικα που ανάλογα το DataRowState φτιάχνει

ο command_builder τα sql querys

Μπορώ να πάρω το ID μετά το

da_Sql.InsertCommand = command_builder.GetInsertCommand()

ή δεν μπορώ?

Ή πρέπει να αλλάξω τον κωδικά μου και να τα κάνω χειροκίνητα

ή πρέπει να γυρίσω τα queries σε store procedures ή ......

ή γιατί πρέπει να μιλάμε για MSSQL2005

Δέν ξερω :)

Όπως μς χαρά θα συμβούλευα ένα με λιγώτερη γνώση από μένα

έτσι θέλω και εγώ να μάθω από κάποιον που ξέρει ποιό πολά από μένα

γιατί σίγουρα κάποιος ξέρει ποιό πολλά από μένα ......

Γιώργος Μ.