Classic ASP

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Mon, 21 Mar 2011 16:55:27 GMT

Απλά για να κλείσει το thread, η λύση του Γιώργου είναι η σωστή, απλά στην asp δεν ισχύουν τα enums για τα CursorLocation, CursorType, κτλ και έπρεπε να βάλω τους σωστούς αριθμούς.

    Set cn = Server.CreateObject("ADODB.Connection")
    cn.ConnectionString = "Provider=SQLOLEDB.1;Password=******;Persist Security Info=True;User ID=******;Initial Catalog=******;Data Source=******"
    cn.CursorLocation = 3
    cn.Open
    
    Set rs = Server.CreateObject("ADODB.Recordset")
    Set rs.ActiveConnection = cn
    rs.CursorLocation = 3
    rs.CursorType = 2
    rs.LockType = 3
    rs.Source = "users"

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Mon, 07 Feb 2011 19:46:24 GMT

Καλημέρα σας,

Γιώργο ευχαριστώ για τον κώδικα. Δεν μου δούλεψε όμως. Στη γραμμή "myConn.CursorLocation = adUseClient", όπου myConn είναι ένα ADODB.Connection object. παίρνω το εξής σφάλμα:

ADODB.Connection error '800a0bb9'

Arguments are of the wrong type, are out of acceptable range, or are in conflict with one another.

Δυστυχώς σήμερα δεν έχω το χρόνο να το κοιτάξω λίγο παραπάνω. Θα το δω κάποια στιγμή (με περισσότερη άνεση χρόνου) και θα επιστρέψω αν έχω κάτι..

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Mon, 07 Feb 2011 17:28:41 GMT

Παρεπιπτόντως, χτες έκανε και την εμφάνισή του το βιβλίο που είχα στο λύκειο για την GW-Basic... μην τα ρωτάτε!!!

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Mon, 07 Feb 2011 17:25:44 GMT

Thanks Γιώργο... απομένει να το δει ο Τάσος μέσα στο σκριπτ, αν και είναι όπως το λές.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

George J. Capnias — Sun, 06 Feb 2011 08:15:16 GMT

Να πω ότι παρακολουθώ το θέμα από την αρχή - και όπως είπε και ο Σωτήρης, θυμήθηκα παλιές εποχές - και νομίζω ότι έχετε κάνει ένα σφάλμα που δεν το έχετε καταλάβει και για αυτό έχετε φτάσει σε ένα σημείο που προσπαθείτε να κάνετε το εύκολο δύσκολο...

Το πρόβλημα που έχετε δεν είναι στο Recordset αλλά στο Connection: Ενώ μια χαρά ανοίγει το Recordset με adUseClient/adOpenDynamic/adLockOptimistic έχετε το Connection με CursorLocation σε adUseServer. Αν γυρίσετε το Connection.CursorLocation σε adUseClient δεν χρειάζεται τίποτα παραπάνω...

Κάπου ξέθαψα ένα VM με WindowsXP SP3, VB6 SP6 και SQL Server 2000 και έκανα την εξής δοκιμή:

Έφτιαξα ένα πίνακα στον SQL Server 2000:

CREATE TABLE [dbo].[Users] (
	[Id] [bigint] IDENTITY (1, 1) NOT NULL ,
	[UserName] [varchar] (50) COLLATE Greek_CI_AS NOT NULL ,
	[FirstName] [varchar] (50) COLLATE Greek_CI_AS NULL ,
	[LastName] [varchar] (50) COLLATE Greek_CI_AS NULL ,
	[Email] [varchar] (50) COLLATE Greek_CI_AS NOT NULL 
) ON [PRIMARY]
GO

ALTER TABLE [dbo].[Users] WITH NOCHECK ADD 
	CONSTRAINT [PK_Users] PRIMARY KEY  CLUSTERED 
	(
		[Id]
	)  ON [PRIMARY] 
GO

Και έτρεξα τον παρακάτω κώδικα από την VB6 (χρησιμοποίησα ADO v2.8)

Private Sub cmdInsertNumber_Click()
Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset

    Set cn = New ADODB.Connection
    cn.ConnectionString = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=ADODB;Data Source=."
    cn.CursorLocation = adUseClient
    cn.Open
    
    Set rs = New Recordset
    Set rs.ActiveConnection = cn
    rs.CursorLocation = adUseClient
    rs.CursorType = adOpenDynamic
    rs.LockType = adLockOptimistic
    rs.Source = "Users"
    rs.Open
    
    rs.AddNew
    rs.Fields.Item("UserName").Value = "gcapnias"
    rs.Fields.Item("Email").Value = "george@capnias.org"
    rs.Update
    
    Debug.Print "Id: " & rs.Fields.Item("Id").Value
    
    rs.Close
    cn.Close
    Set cn = Nothing
    
End Sub

Αν το Recordset δεν έχει το Id θα χτυπήσει στην γραμμή 23, αλλά δεν το κάνει - σε κάθε εκτέλεση το Id είναι εκεί και εκτυπώνεται...

George J.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Sat, 05 Feb 2011 03:01:31 GMT

Δεν νομίζω να σε χαλάσει που είναι VB6, το ADODB είναι ίδιο.

Δες αυτό, αν θες θα σου ανεβάσω και το project, αλλά θες VS6

Dim conn As New ADODB.Connection

Private Sub Form_Load()
    conn.ConnectionString = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=ProvingGround;Data Source=INFERNO\SQLEXPRESS"
    conn.CursorLocation = adUseServer
    conn.Open
End Sub

Private Sub buttonAddNew_Click()
                    
    'Ορισμός recordset, τσιμπάει τον πίνακα
    Dim rs As New ADODB.Recordset
    rs.Open "SELECT * FROM RECORDS", conn, adOpenStatic, adLockOptimistic

    'Κάνει addnew
    rs.AddNew
    rs.Fields(1).Value = "Hello world"
    rs.Update
    
    MsgBox (rs.RecordCount)
    
    'Κλείνει το recordset!!!
    rs.Close
    
    'Και μέσω του ίδιου ψευτοαντικειμένου τρέχεις το νέο command
    rs.Open "SELECT @@IDENTITY FROM RECORDS", conn, adOpenStatic, adLockOptimistic
    
    'Voila
    dump = MsgBox(rs.Fields(0).Value)
    
    'Και για να είμαστε τυπικοί...
    rs.Close
    Set rs = Nothing
    
End Sub

Private Sub Form_Unload(Cancel As Integer)
    conn.Close
    Set conn = Nothing
End Sub

Σημείωσε ότι το τρέχω στο ίδιο αντικείμενο. Δεν δοκίμασα να φτιάξω άλλο command, όπως σου είπα πριν

ΕΠΙΣΗΣ!!!!

Δοκίμασα και αυτήν την παραλλαγή για να προσεγγίσω το δικό σου παράδειγμα όπου κάθε φορά φτιάχνεται το connection και δεν υπάρχει στην μνήμη, και δουλεύει επίσης κανονικά.

Private Sub Form_Load()

End Sub

Private Sub buttonAddNew_Click()

    Dim conn As New ADODB.Connection
    conn.ConnectionString = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=ProvingGround;Data Source=INFERNO\SQLEXPRESS"
    conn.CursorLocation = adUseServer
    conn.Open
    
    Dim rs As New ADODB.Recordset
    rs.Open "SELECT * FROM RECORDS", conn, adOpenStatic, adLockOptimistic

    rs.AddNew
    rs.Fields(1).Value = "Hello world"
    rs.Update
    
    MsgBox (rs.RecordCount)
    
    rs.Close
    
    rs.Open "SELECT @@IDENTITY FROM RECORDS", conn, adOpenStatic, adLockOptimistic
    
    dump = MsgBox(rs.Fields(0).Value)
    
    rs.Close
    Set rs = Nothing
    
    conn.Close
    Set conn = Nothing

End Sub Private Sub Form_Unload(Cancel As Integer)

End Sub

Το συμπέρασμα είναι ότι μάλλον πρέπει να κάνεις την τροποποίηση κάπως έτσι:

Set Rst = Server.CreateObject("ADODB.Recordset")
Rst.Open "Mail",Cn,2,3
Rst.AddNew
	Rst.Fields(1)=trim(request.form("MName"))
	Rst.Fields(2)=trim(request.form("MAddress"))
	Rst.Fields(3)=trim(request.form("MCity"))
	Rst.Fields(4)=trim(request.form("MZipCode"))
	Rst.Fields(5)=trim(request.form("MCountry"))
	Rst.Fields(6)=trim(request.form("MTele"))
	Rst.Fields(7)=trim(request.form("MMobile"))
Rst.Update

'*************************************************
'*************************************************

Rst.Close
Rst.Open "SELECT @@IDENTITY FROM Mail", conn, adOpenStatic, adLockOptimistic
NewID = Rst.Fields(0).Value

'Και κλεισίματα από δω και κάτω

Τι να πω, σε μένα δουλεύει κανονικά πάντως... και δεν νομίζω να έχει σημασία το ότι είναι ASP, η βάση είναι το Ado.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Fri, 04 Feb 2011 23:42:05 GMT

dimos.homatas:
Οπότε φτιάξε μία function που να τσιμπάει το εκάστοτε id, και πάνε κόλλα την πριν το close.

Α, πρέπει να φτιάξεις ένα adodb.command που να κάνει αυτήν την δουλειά :)

Την έφτιαξα την command και κατέληξα εδώ:

Set Rst = Server.CreateObject("ADODB.Recordset")
Rst.Open "Mail",Cn,2,3
Rst.AddNew
	Rst.Fields(1)=trim(request.form("MName"))
	Rst.Fields(2)=trim(request.form("MAddress"))
	Rst.Fields(3)=trim(request.form("MCity"))
	Rst.Fields(4)=trim(request.form("MZipCode"))
	Rst.Fields(5)=trim(request.form("MCountry"))
	Rst.Fields(6)=trim(request.form("MTele"))
	Rst.Fields(7)=trim(request.form("MMobile"))
Rst.Update
Set myComm = Server.CreateObject("ADODB.Command")
myComm.ActiveConnection = Cn
myComm.CommandText = "SELECT @@IDENTITY FROM Mail;"
NewID = myComm.Execute
MailID = NewID(0)
Rst.Close

Το πρόβλημα είναι ότι αν τρέξω τον ίδιο κώδικα (με refresh της σελίδας) παραπάνω φορές (δηλαδή, κάνω και μία 2η, 3η κτλ εισαγωγή στο σύστημα) το MailID δεν έχει τιμή!! Μόνο την πρώτη πρώτη φορά παίρνω το ID της νέας εγγραφής και αν κάνω νέα εισαγωγή δεν παίρνω κάποια τιμή για το ID.

Υπάρχει κάποιο λάθος στον παραπάνω κώδικα που μου διαφεύγει...;

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Fri, 04 Feb 2011 06:57:31 GMT

Τάσο πως το έλεγε το άλλο;

"THE JANITOR: Converted a VB 6 project to VB.NET"

Ρετρό!

Βλέπω εδώ στην αποθήκη κάτι ωραία modules .BAS με ... 2000 γραμμές γεμάτες functions που πηγαινοφέρνουν διάφορα από και προς την ΒΔ!

Ένα DAL, κατά κάποιο τρόπο...

Τάσο ναι, κλασσικό sql για να τσιμπάς το σχήμα του πίνακα... πω πω πω, έτσι όπως πάμε θα ανοίξουμε και κάνα thread για GW-Basic, είμαι σίγουρος ότι έχω κάπου!!!

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Fri, 04 Feb 2011 06:41:37 GMT

dimos.homatas:
Ναι, και μάλιστα δεν είναι disconnected σαν αυτά που έχουμε στο ADO.NET. Από εκεί βγαίνει και το filter.

Αυτά είναι! Άρα θα δοκιμάσω κάτι τύπου SELECT * FROM Mail WHERE (1=0), το είδα κάπου κ αυτό. Η αλήθεια είναι ότι ψάχνω για κάποιον ανώδυνο τρόπο, αφού η εφαρμογή θα "ζήσει" για λίγους μήνες ακόμα.

cap:
Αν και off topic, θα ήθελα να σας συγχαρώ όλους εσάς που μου θυμίσατε τα χρόνια της νιότης μου :)

Χε χε, πολύ δραματικό μου φάνηκε αυτό! By the way, το πρώτο μου web application με asp και access ήταν (πρακτική στο πανεπιστήμιο), αλλά πάει πολύς καιρός από τότε κ δεν θυμάμαι σχεδόν τίποτα...

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

cap — Fri, 04 Feb 2011 06:38:43 GMT

Αν και off topic, θα ήθελα να σας συγχαρώ όλους εσάς που μου θυμίσατε τα χρόνια της νιότης μου :)

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Fri, 04 Feb 2011 06:36:36 GMT

tasos:

Να βάλω filter με όλα τα πεδία για τα οποία έδωσα τιμές. Καλή ιδέα, αν τελικά καταλήξω στη μαϊμουδιά!

Θα δουλέψει, και μάλιστα εκτελείται στο client... Νομίζω! Δεν ξαναρωτά τον server.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Fri, 04 Feb 2011 06:34:01 GMT

Ναι, και μάλιστα δεν είναι disconnected σαν αυτά που έχουμε στο ADO.NET. Από εκεί βγαίνει και το filter.

Βέβαια μπορείς να έχεις και σύνταξη πχ

dim rs as new adodb.recordset

rs.open "select whatever", connection, cursortype, locktype

'do stuff

rs.close

ΚΑΙ:

set rs = nothing (έτσι για να μην ξεχνιόμαστε!)

Πολύ ρετρό μιλάμε... και όμως έχω εφαρμογές που παίζουν χρόνια και χρόνια με αυτά!

Ευτυχώς που τα αφήσαμε πίσω μας... αν και για vbscript καλό είναι το adodb.

Τι να σου πω Τάσο, εφ'όσον το να το πετάξεις και να το κάνεις καινούριο δεν αποτελεί viable option, κάντο με τον πιο ανώδυνο (για σένα) τρόπο.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Fri, 04 Feb 2011 06:28:33 GMT

dimos.homatas:
Εναλλακτικά βέβαια, θα μπορούσες να τροποποιήσεις την πατέντα που έκανες και να την κάνεις πιο ασφαλή: το recordset έχει μέθοδο filter. Μπορείς να κάνεις ένα filter με τα στοιχεία που έχεις ήδη από την φόρμα. Αυτό που θα απομείνει θα είναι η τελευταία εγγραφή που έβαλες.

Βέβαια κοστίζει πολύ. Επίσης εάν είναι εφικτό να υπάρχουν πανομοιότυπες εγγραφές, πάλι πρόμπλεμ... αν και θα μπορούσες να πάρεις την τελευταία.

Το θέμα είναι ότι αυτά είναι μαιμουδιές και πατέντες, αλλά εάν δεν δουλέψει τίποτα άλλο, γιατί όχι;

Και στο κάτω κάτω εάν ο πελάτης δεν πληρώνει για νέα εφαρμογή, αυτό φτάνει και περισσεύει!

Να βάλω filter με όλα τα πεδία για τα οποία έδωσα τιμές. Καλή ιδέα, αν τελικά καταλήξω στη μαϊμουδιά!

Το project είναι μία αρκετά μεγάλη υλοποίηση που έγινε με asp και access. Και ήρθε η ώρα της αναβάθμισης σε κάτι πιο σύγχρονο. Σε 1η φάση θέλουμε να πάει σε sql server και ο κύριος λόγος είναι οι άλλες εφαρμογές μας που είναι asp.net να μπορέσουν να δουν αυτά τα δεδομένα (που μέχρι τώρα δεν μπορούσαν). Οπότε είπαμε να κάνουμε τη μετάβαση σε sql server, και έτσι να "ενώσουμε" τις εφαρμογές μας. Η 1η φάση είναι σε επίπεδο δεδομένων και μετά ξεκινάμε με την ενοποίηση τους σε μία μεγάλη εφαρμογή όπου όλα θα είναι όμορφα κ συμμαζεμένα.

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

tasos — Fri, 04 Feb 2011 06:16:59 GMT

Έλα ρε Δήμο, τι να πω με μπλέξανε...

Πολύ καλό το αρθράκι που βρήκες! Η function που λες πρέπει να εκτελεί το "SELECT SCOPE IDENTITY();" στο ανοιχτό recordset, σωστά;

Πάντως, αυτό που λένε σε ένα σημείο είναι ότι μπορείς να βάλεις το property adResyncAutoIncrement στο recordset και όταν καλέσεις την UpdateBatch (και όχι την update) να κάνει resync και να φέρει ξανά το row, μαζί με το νέο id. Και ψάχνοντας λοιπόν να δω πως θα ορίσω αυτό το property βρήκα εδώ (http://www.tech-archive.net/Archive/Data/microsoft.public.data.ado/2006-08/msg00209.html) το εξής sample:

RS.Properties("Update Resync") = adResyncInserts + adResyncAutoIncrement
RS.Properties("Resync Command") = "SELECT * FROM myTable WHERE ID IN (SELECT @@IDENTITY FROM myTable)"

Βέβαια έχει μία λίστα με ενστάσεις, και μία από αυτές είναι το performance.

Και μία δεύτερη ερώτηση που προέκυψε με τα όσα διάβασα σήμερα σχετικά με το ADO: Στον κώδικα μου, όταν καλώ το Rst.Open "Mail",Cn,2,3, φέρνει όλα τα rows του πίνακα Mail; Είναι δηλαδή ισοδύναμο με το Rst.Open "SELECT * FROM Mail",Cn,2,3;

Απ: Εφαρμογή με classic asp και MS Access, μετφορά δεδομένων σε Sql Server.

dimos.homatas — Fri, 04 Feb 2011 05:39:15 GMT

Εναλλακτικά βέβαια, θα μπορούσες να τροποποιήσεις την πατέντα που έκανες και να την κάνεις πιο ασφαλή: το recordset έχει μέθοδο filter. Μπορείς να κάνεις ένα filter με τα στοιχεία που έχεις ήδη από την φόρμα. Αυτό που θα απομείνει θα είναι η τελευταία εγγραφή που έβαλες.

Βέβαια κοστίζει πολύ. Επίσης εάν είναι εφικτό να υπάρχουν πανομοιότυπες εγγραφές, πάλι πρόμπλεμ... αν και θα μπορούσες να πάρεις την τελευταία.

Το θέμα είναι ότι αυτά είναι μαιμουδιές και πατέντες, αλλά εάν δεν δουλέψει τίποτα άλλο, γιατί όχι;

Και στο κάτω κάτω εάν ο πελάτης δεν πληρώνει για νέα εφαρμογή, αυτό φτάνει και περισσεύει!