Πρώτα Βήματα - Αρχές προγραμματισμού

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

Libra Storm — Mon, 30 May 2011 05:09:03 GMT

Νά σαι καλά! Πρέπει να αλλάξεις κάποια πράγματα(κια) μόνος σου γιά να δουλέψει όπως πρέπει.

Κατ' αρχήν πρέπει να βρεις έναν τρόπο να βγάλεις το boolean _bFirstTime. Επειδή είναι α) κακό να έχεις private flags τέτοιου τύπου και β) το function καλείται χιλιάδες φορές και ο παραμικρός έλεγχος καθυστερεί το πρόγραμμά σου. (Δοκίμασε να αλλάξεις το method από DrawLine σε DrawLines που παίρνει σαν παράμετρο array από points και να δεις έτσι τι perfomance gain έχεις).

Βγάλε τα Hard Coded νούμερα και φτιάξε το Class με τέτοιον τρόπο που να παίρνει εύρος τιμών από το visible area της φόρμας αφού θα πρέπει ο χρήστης να μπορεί με το mouse να κάνει scroll και zoom (με το ctrl + mouse wheel ίσως) σε όποιο σημείο της παράστασης επιθυμεί.

Φτιάξε ένα control και βάλε τον κώδικα εκεί γιά να μπορείς να το χρησιμοποιείς παντού. (Άλλαξε το Step σε 0.001 και δες ότι μόλις ξεκινάει το πρόγραμμα κάθε φορά που προστίθεται ένα control στην φόρμα (Command button) ξαναζωγραφίζεται η παράσταση από την αρχή. Με το Control θα το γλυτώσεις αυτό εύκολα).

To invalidate καλεί το OnPaint method το οποίο με την σειρά του "σηκώνει" το paint event. Πάτα το button που ζωγραφίζει το bitmap και μετά το button paint. αλλοιώς γιά να ξαναδείς την γραφική παράσταση θα πρέπει να κάνεις κάποια κίνηση που να το καλέσει όπως π.χ. minimize και restore.

Ρίξε μιά ματιά στο microsoft math αν θέλεις γιά να πάρεις ιδέες.

Καλή επιτυχία και καλό λυώσιμο.

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

AlKiS — Sun, 29 May 2011 23:44:25 GMT

Νομίζω οτι αυτό είναι ακριβώς αυτό που ζητάω.

Αν και το κουμπί "paint" δεν κάνει τίποτα για κάποιο λόγο, το bitmap ζωγραφίζει πάνω στην φόρμα!

Οπότε θα κάτσω να διαβάσω τον κώδικά σου για να καταλάβω τι κάνεις.

Σε ευχαριστώ πάρα πολύ φίλε! έχεις και επεξηγήσεις μέσα, θα σου πήρε χρόνο.

Ευχαριστώ, είσαι φοβερός!

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

Libra Storm — Sun, 29 May 2011 22:42:17 GMT

Στο namespace System.Drawing έχει κλάσεις που μπορείς να χρησιμοποιήσεις γιά να ζωγραφίσεις. Μία από αυτές είναι η Class Graphics (System.Drawing.Graphics). Έχεις δύο τρόπους να την χρησιμοποιήσεις. Από το Paint Event ενός control ή από το Protected OnPaint. Μπορείς ακόμα να δημιουργήσεις δικό σου Graphics object όποτε το χρειαστείς. Δες το ακόλουθο Link γιά να ξεκινήσεις. http://msdn.microsoft.com/en-us/library/da0f23z7.aspx

Γενικά υπάρχουν δύο τρόποι γιά να δημιουργήσεις γραφικές παραστάσεις. Ένας τρόπος είναι να ενώσεις μικρές γραμμές και ο άλλος είναι να κάνεις SetPixel σε Bitmap.Διάβασε αν θέλεις και τον παρακάτω κώδικα που έχει μικρά παραδείγματα . Φτιάξε μία φόρμα και βάλε 3 command button απάνω της.

Option Strict On

Public Class Form1
    ' Μπορείς να ζωγραφίσεις είτε στο paint event παίρνωντας το Graphics Object
    Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles Me.Paint
        Dim ctn As New Cartesian(e.Graphics)
        ''Dim X As Single
        ''Dim Y As Single

        ctn.Origin = New PointF(200, 200)

        e.Graphics.SmoothingMode = Drawing2D.SmoothingMode.HighSpeed

        ctn.DrawAxes()

        e.Graphics.SmoothingMode = Drawing2D.SmoothingMode.AntiAlias

        ''For X = -10 To 50 Step 0.5!
        ''    Y = CType((Math.Sin(X)), Single)

        ''    ctn.Draw(New PointF(X, Y))
        ''Next

        ' Αν σε μπερδεύει το Delegate κάνε uncomment το προηγούμενο block
        ctn.Draw(AddressOf aFunction)
    End Sub

    ' Είτε στο OnPaint αν θές να κληρονομείται
    Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
        ' Μπλα Μπλα
        MyBase.OnPaint(e)
    End Sub

    ' Νπορείς επίσης να δημιουργήσεις Graphics Object όποτε το χρειάζεσαι.
    Private Sub cmdBitMap_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdBitMap.Click
        Dim g As System.Drawing.Graphics = Me.CreateGraphics

        Me.BitmapPlot(g)
        g.Dispose()
    End Sub

    Private Sub cmdClear_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdClear.Click
        Dim g As Drawing.Graphics = Me.CreateGraphics

        g.Clear(Me.BackColor)
        g.Dispose()
    End Sub

    Private Sub BitmapPlot(ByVal graphics As Drawing.Graphics)
        Dim bmp As New Bitmap(255, 255)

        ' Plot, Αν θές απόλυτο έλεγχο ανά pixel
        ' Δες και παράδειγμα με Lockbits αν θες καλύτερο perfomance
        ' http://msdn.microsoft.com/en-us/library/system.drawing.bitmap.lockbits.aspx

        For i As Integer = 0 To bmp.Width - 1
            For n As Integer = 0 To bmp.Height - 1
                bmp.SetPixel(i, n, Color.FromArgb(255, 255 - i, i, i))
            Next
        Next

        graphics.DrawImage(bmp, 0, 0)
        bmp.Dispose()
    End Sub

    Private Sub cmdPaint_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles cmdPaint.Click
        Me.Invalidate(False)
    End Sub

    Private Function aFunction(ByVal X As Single) As Single
        Return CType((Math.Sin(X)), Single)
    End Function
End Class

Public Class Cartesian
    Public Property Origin As PointF
    Public Property Graphics As System.Drawing.Graphics

    Private _PreviousPoint As PointF
    Private _bFirstTime As Boolean

    Public Sub New(ByVal graphics As System.Drawing.Graphics)
        Me._Graphics = graphics
        Me._bFirstTime = True
    End Sub

    Public Sub DrawAxes()
        Dim fnt As New Font("Arial", 8.0!)

        _Graphics.DrawLine(Pens.LightGray, 0, Origin.Y, 1000, Origin.Y)
        _Graphics.DrawLine(Pens.LightGray, Origin.X, 0, Origin.X, 1000)
        _Graphics.DrawString("(0,0)", fnt, Brushes.Orange, Origin)

        fnt.Dispose()
    End Sub

    Public Sub Draw(ByVal point As PointF)
        point.X *= 10 ' Ζουμαρε λίγο
        point.Y *= 10

        point = PointF.Add(point, New SizeF(Origin.X, Origin.Y - 2 * point.Y))

        If _bFirstTime Then
            _bFirstTime = False
            _PreviousPoint = point
            Return
        End If

        Dim pen As New Pen(Drawing.Color.Black, 1.6!)

        _Graphics.DrawLine(pen, _PreviousPoint, point)
        pen.Dispose()

        _PreviousPoint = point
    End Sub

    Public Sub Draw(ByVal MyFunction As Func(Of Single, Single))
        Dim X As Single
        Dim Y As Single

        For X = -10 To 50 Step 0.6!
            Y = MyFunction(X)
            Me.Draw(New PointF(X, Y))
        Next

        Me._bFirstTime = True
    End Sub
End Class

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

AlKiS — Sun, 29 May 2011 04:20:25 GMT

ευχαριστώ, θα το ψάξω :)

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

Pak — Sun, 29 May 2011 03:44:21 GMT

ALKI

Αν δουλέυεις με VS 2010 αυτό θα σε βοηθήσει

http://archive.msdn.microsoft.com/mschart

υπάρχουν αρκερά παραδείγματα που δείχνουν πώς να χρησιμοποιήσεις τα chart controls

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

AlKiS — Sun, 29 May 2011 01:42:46 GMT

Αυτό είναι που θέλω, ναί.

Ωστόσο δεν έχω ιδέα πως θα κάνω το draw. και πού??? στην ίδια τι φόρμα? σε picturebox? ή υπάρχει κάτι ειδικά γι αυτό???

Απο μαθηματικά δεν υπάρχει πρόβλημα, ξέρω απο πρόσθεση μέχρι μετασχηματισμούς laplace και σειρές fourie...

Το θέμα είναι -που- και -πως- να "ζωγραφίσω" τα points και πως να τα ενώσω σε ευθεία ή καμπύλη

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

panagiotis_georgiadis — Sat, 28 May 2011 23:19:42 GMT

Με την υπόθεση ότι ξέρεις VB και μαθηματικά, κάπως έτσι θα άρχιζε κανείς ένα τέτοιο πρόγραμμα.
Έχεις μία συνάρτηση y=f(x) και θέλεις να την απεικονίσεις στην οθόνη.
Το κύριο πρόβλημα (όπου θα χρειαστείς αλγόριθμο) είναι ότι τα Χ και Υ είναι δεκαδικοί αριθμοί, και η οθόνη σου αποτελείεται από pixel, που είναι θετικοί ακέραιοι.
Έστω ότι το Χ της συνάρτησης έχει τιμές μεταξύ -2.5 και +2.5 και σταθερό Δχ = 0.1
Έστω ότι το παράθυρο (ή control παρόμοιου τύπου) έχει συντεταγμένες οριζόντιου άξονα από 10 ώς 510, δηλαδή width = 500 pixel
Άρα έχεις να απεικονίσεις (x_max - x_min)/Δ_χ= 50 τιμές σε 500 pixel. Άρα 10 pixel κενό ανάμεσα σε 2 συνεχόμενες τιμές. Αν τα χ είναι αποθηκευμένα σε ένα πίνακα χ[50], τότε θες ένα βρόχο που κάνει περίπου το εξής:

x_left = 10
dx = 10
για καθε i, από 0 ώς 49 :

    x_coordinate_next = x_left + dx * i
    draw_point (x_coordinate_next)

Το ίδιο περίπου και για τα Υ, και για τα Υ(Χ)
Η δουλειά σου είναι να κάνεις τον ψευδοκώδικα VB.NET κώδικα, αφού βρεις και τις συναρτήσεις που ζωγραφίζουν (εδώ τη λέω draw_point απλά για να σου δείξω πού γίνεται το ζωγράφισμα)

Αν δεν ήταν αυτό που ζητούσες, διευκρίνισε τι ακριβώς σε δυσκολεύει.

Απ: VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

Markos — Fri, 27 May 2011 23:15:20 GMT

Αν ψάξεις στο CodeProject θα βρεις αρκετά άρθρα που καταπιάνονται με τη δημιουργία τέτοιου είδους components, όπως αυτό και αυτό. Δυστυχώς, είναι γραμμένα σε c# και δε γνωρίζω αν υπάρχει κάτι δημοσιευμένο σε vb.net. Ακόμα κι αν δε σου αρέσει η c# ή/και δε θέλεις να γράφεις σ' αυτήν, τουλάχιστον μάθε να τη "διαβάζεις" γιατί θα σου λύσει τα χέρια.

VB.net Γραφική Παράσταση (Ευθεία/Καμπύλη)

AlKiS — Fri, 27 May 2011 16:48:05 GMT

Καλημέρα,

Ασχολούμαι με τον προγραμματισμό ως χόμπι για πολλά χρόνια τώρα πια, δυστυχώς όσο κιαν μου αρέσει, λόγω σχολείο παλιότερα και λόγω σχολής τώρα, δεν είχα το χρόνο να μάθω τόσο καλό προγραμματισμό.

Θέλω να φτιάξω ένα πρόγραμμα, αυτή τη φορά, το οποίο θα του δίνουμε κάποια σημεία, και θα μας κάνει την γραφική παράσταση

Αν και κάθε άλλη φορά που ζήτησα βοήθεια είχα κάτι ήδη σχεδόν τελειωμένο έχοντας μόνο μια απορία - αυτή τη φορά δεν έχω ιδέα πως να αρχίσω καν.

Ευχαριστώ πολύ όποιον με καθοδηγήσει στο να μάθω να κάνω άξονες Χ'Χ/Υ'Υ και καμπύλες/ευθείες πάνω στους άξονες, σε VB.NET 2010.