Πρώτα Βήματα - Αρχές προγραμματισμού

Απ: Πρόβλημα με Async σε richTextBox

Libra Storm — Sat, 03 Mar 2012 10:16:32 GMT

Δοκίμασε το παρακάτω και θα σου δουλέψει με Option strict on

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim result As IEnumerable(Of Tuple(Of String, Integer, Integer))

        result = SearchWords("SELECT * FROM MyTable", New String() {"SELECT", "FROM"})

        For Each r As Tuple(Of String, Integer, Integer) In result
            Console.WriteLine("Value: {0} Index: {1} Length: {2}", r.Item1, r.Item2, r.Item3)
        Next
    End Sub

    Function SearchWords(input As String, words As String()) As IEnumerable(Of Tuple(Of String, Integer, Integer))
        Dim pattern As String = String.Join("|", words)
        Dim matches As MatchCollection = Regex.Matches(input, pattern)

        Dim indexes As IEnumerable(Of Tuple(Of String, Integer, Integer)) =
            From m As Match In matches.Cast(Of Match)()
            Select Tuple.Create(m.Value, m.Index, m.Length)

        Return indexes
    End Function

Το IEnumerable είναι Interface. Το συγκεκριμένο Interface μας βοηθάει στο να μπορούμε να κάνουμε for each σε μία σειρά ή ακολουθία από αντικείμενα όπως πχ τα controls μίας φόρμας ή τις γραμμές ενός Datatable. Στο συγκεκριμένο παράδειγμα δεν θα μπορούσα να κάνω for each αν το function δεν γύρναγε το Interface αυτό ή κάποιο άλλο class που να το περιέχει (ή πιό σωστά να το κάνει implements).

Το tuple είναι μία δομή που μας βοηθάει να οργανώνουμε πληροφορίες σε μία "σειρά". ΠΧ αν θέλουμε να περάσουμε πολλά byref σαν παραμέτρους σε ένα function μπορούμε να το χρησιμοποιήσουμε. Επίσης σε περίπτωση που ένα function θέλουμε να γυρνάει πληροφορίες γιά κάτι, πχ τα στοιχεία ενός πελάτη (όνομα τηλέφωνο διεύθυνση κλπ) μπορούμε επίσης να το χρησιμοποιήσουμε. Το μοναδικό του "Μειονέκτημα" είναι ότι πρέπει να ξέρουμε τι πληροφορία πρέπει να βάλουμε στα στοιχεία του αφού αναφέρεται σε αυτά (όπως στο παράδειγμα) σαν item1, item2 κλπ.

To μυστήριο μύνημα "exception has been thrown bla bla bla" πάει να πει ότι λές σε κάποιον να κάτι, δεν τα καταφέρνει και αντί να σου πει γιατί δεν τα κατάφερε σου λέει απλά ότι δεν δεν τα κατάφερε... Παράδειγμα:

Option Strict On
Option Infer Off

Imports System.Reflection

Public Class Form1
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Try
            Dim oResult As Object
            Dim div As New Division

            oResult = div.GetType.InvokeMember(
                "Divide",
                BindingFlags.InvokeMethod Or
                    BindingFlags.NonPublic Or
                    BindingFlags.Instance,
                Type.DefaultBinder,
                div,
                {10, 0})

            MessageBox.Show(oResult.ToString)
        Catch ex As Exception
            If ex.InnerException IsNot Nothing Then
                MessageBox.Show(ex.InnerException.ToString) ' Το exception που προκάλεσε το Invocation exception.
            End If

            MessageBox.Show(ex.ToString) ' Όλο το μύνημα.
        End Try
    End Sub
End Class

Public Class Division
    ' Μήπως παρατηρείς τίποτα "παράξενο"
    ' εδώ;
    Private _
    Function Divide(x As Integer, y As Integer) As Integer
        Return x \ y
    End Function
End Class

Το inner Exception στο παράδειγμα σου λέει τι πραγματικά συνέβη.

Όσον αφορά την περίπτωση που εσύ λες ότι μπoρεί κάποιος να έχει ένα σενάριο 12000000 γραμμών σε ένα RichTextBox, μπορεί σε κάποιο μηχάνημα να δουλεύει αλλά στο δικό μου θα βγει το CPU από το τροφοδοτικό (μαζί με τις μνήμες).

ϊσως θα μπορούσες να γράψεις το κατεβατό σε αρχείο και να το διαβάζεις κομμάτι κομμάτι κάνωντας και τις αλλαγές στα χρώματα, έτσι θα κερδίσεις και μνήμη και ταχύτητα. Υπάρχει ένα μεγάλο πρόβλημα με το richtextbox βέβαια, το ότι δεν ξέρεις την τιμή που έχει το Scrollbar ή την θέση του cursor γιά να προφορτώσεις τις επόμενες σελίδες και η ταχύτητα που μπορεί κάποιος να το ανεβοκατεβαζει να είναι τόσο μεγάλη, που να μην μπορείς να διαβάσεις γρήγορα το αρχείο και να δείξεις το τμήμα που αντιστοιχεί στην συγκεκριμένη θέση. Δεν μου έχει τύχει παρόμοια περίπτωση με τόσο μεγάλα αρχεία γιά να είμαι ειλικρινής.

Το async και το await είναι βολικά αλλά και τα Task από μόνα τους δεν είναι δύσχρηστα. Το παρακάτω παράδειγμα σου λέει πως να φτιάξεις ένα class το οποίο εκτελεί ένα Sub και μόλις τελειώσει σου στέλνει ένα event. Η νοοτροπία του να βάζουμε τέτοιες διαδικασίες σε classes είναι πολύ καλή κατά την γνώμη μου. Καλά είναι και τα Async await αλλά φοβάμαι ότι η αλόγιστη χρήση τους μπορεί ναι οδηγήσει σε δυσανάγνωστο κώδικα.

Option Strict On
Option Infer Off

Imports System.Threading.Tasks

Public Class Form1
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Try
            Me.Text = "Start"
            Dim t As New NotifyTask(AddressOf DoSomething, AddressOf TaskFinished)

            Me.Button1.Enabled = False
        Catch ex As Exception
            MessageBox.Show(ex.ToString)
        End Try
    End Sub

    Private Sub DoSomething()
        Threading.Thread.Sleep(3000)
    End Sub

    Private Sub TaskFinished(sender As System.Object, e As System.EventArgs)
        Try
            Me.Text = "Done"
            Me.Button1.Enabled = True ' Δεν χρειάζεται να κάνεις invoke δες παρακάτω γιατί.
        Catch ex As Exception
            MessageBox.Show(ex.ToString)
        End Try
    End Sub
End Class

' -------------------------------------------------------------------------------------

Public Class NotifyTask
    ' Θα μπορούσες να κληρονομήσεις το EventArgs και να φτιάξεις δικό σου, 
    ' π.χ. TaskEventArgs γιά να σου γυρίζει και το Task με τα όποια λάθη έχει και, 
    ' να το περάσεις σαν παράμετρο στην WhenFinished As EventHandler(Of TaskEventArgs).
    Public Sub New(SubToCall As Action, WhenFinished As EventHandler(Of EventArgs))
        Try
            If SubToCall Is Nothing Then Throw New ArgumentNullException("SubToCall")

            AddHandler Me.TaskEnd, WhenFinished

            Task.Factory.StartNew(SubToCall).
                ContinueWith(AddressOf EndTask, TaskScheduler.FromCurrentSynchronizationContext)

            ' Αν σε δυσκολεύει η παραπάνω σύνταξη δες αυτήν.
            ''Dim tsk As Task = Task.Factory.StartNew(SubToCall)
            ''Dim tsk2 As Task = tsk.ContinueWith(AddressOf EndTask, TaskScheduler.FromCurrentSynchronizationContext)

            ' Οι παραπάνω 2 γραμμές λένε:
            ' 1. Ξεκίνα ένα task που θα τρέξει σε νέο thread και
            ' 2. μόλις τελειώσει, συνέχισε (ContinueWith) με ένα άλλο Task που θα τρέξει στο thread από το οποίο φτιάχτηκε το Class NotifyTask.
            '    (Στην δική μας περίπτωση στο κυρίως Thread).

            ' Γιά αυτόν τον λόγο βάλαμε το "μυστήριο" TaskScheduler.FromCurrentSynchronizationContext σαν παράμετρο στο 2ο Task.
            ' Με αυτόν τον τρόπο όταν κληθεί το Sub TaskFinished από το TaskEnd event, δεν χρειάζεται να κάνεις Me.InvokeRequired και invoke,
            ' γιατί θα τρέξει στο thread που φτιάξαμε το UI (User Interface).
        Catch
            Throw
        End Try
    End Sub

    Private Event TaskEnd As EventHandler(Of EventArgs)

    Private Sub EndTask(ByVal task As Task)
        RaiseEvent TaskEnd(Me, New EventArgs)
    End Sub
End Class

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 22:56:43 GMT

Στο Function μου βγάζει πρόβλημα. Έκανα αλλαγή αλλά και πάλι δεν το παίρνει.

    Function SearchWords(input As String, words As String()) As IEnumerable(Of Tuple(Of String, Integer, Integer))

        Dim pattern As String = String.Join("|", words)
        Dim matches As System.Text.RegularExpressions.MatchCollection = Regex.Matches(input, pattern)
        Dim indexes = From m As Match In matches
                      Select Tuple.Create(m.Value, m.Index, m.Length)
        Return indexes
    End Function

πρόβλημα: Error 1 Option Strict On disallows implicit conversions from 'Object' to 'System.Text.RegularExpressions.Match'. C:\Users\Giannis M\Dropbox\Visual Basic 2010\Projects\StatREC\StatREC\frmMain.vb 941 28 StatREC

Ακόμα κι αν βάλω "Dim indexes As System.Text.RegularExpressions.Match = From m As Match In matches" πάλι το ίδιο μου λέει. Δεν καταλαβαίνω γιατί.

Χρηάζομαι επίσης επεξήγηση στα εξής:

As IEnumerable, τι είναι αυτο???

Of Tuple, Τι είναι αυτό? τη λέξη αυτή δεν την ξέρω καν στα αγγλικά.

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 22:17:34 GMT

Πολύ ωραίο αυτό!

Μπορώ να ενοποιήσω λοιπόν όλα τα searches που έχω για το συγκεκριμένο rtb σε ένα και μόνο (αφού αυτά αλλάζουν τα ίδια χρώματα και bold στο κείμενο).

Ευχαριστώ πολύ για τον κώδικα! Θα τον δω, θα τον προσαρμόσω στο πρόγραμμά μου, και κατόπιν θα κάνω πόστ το αποτέλεσμα.

Μια τελευταία ερώτηση: Ποια εντολή είναι LINQ? (δυστυχώς δεν είχα χρόνο να διαβάσω για LINQ ακόμα, αλλά έχω σημειωμένο να το κάνω)

Απ: Πρόβλημα με Async σε richTextBox

Παναγιώτης Καναβός — Fri, 24 Feb 2012 21:52:03 GMT

Αν κάτι χρειάζεται async είναι η ColoriseRTB. Αυτό όμως δεν γίνεται καθώς ο κώδικας έχει τα ίδια προβλήματα με τον προηγούμενο. Η ColoriseRTB εξακολουθεί να "πειράζει" τα controls οπότε απαιτείται Invoke. Επιπλέον, η Colorise κάνει δύο πράγματα, ψάχνει για λέξεις και αλλάζει τα controls. Αυτό είναι λάθος σχεδιασμός και ένα από τα αποτελέσματα του είναι ότι δεν μπορεί να εκτελεστεί ασύγχρονα.

Τουλάχιστον αυτή η μέθοδος θα πρέπει να σπάσει στα δύο, μία SearchWords η οποία θα έχει ως παρεμέτρους τις γραμμές που πρέπει να αναζητηθούν και θα επιστρέφει τα locations, και μία colorize η οποία με βάση αυτή τη λίστα θα αλλάζει το χρώμα των λέξεων. Η SearchWords άνετα μπορεί να εκτελεστεί ασύγχρονα. Η Colorize όχι.

Μπορούν να γίνουν και άλλες απλοποιήσεις, όπως πχ. να χρησιμοποιηθεί η RichTextBox.Select αντί για την αλλαγή των selection μέσω properties, για να μειωθούν οι καθυστερήσεις που οφείλονται στην επεξεργασία των αλλαγών των properties (π.χ. changed events, πιθανά redraws).

Τέλος, αν ο αριθμός των λέξεων είναι μικρός μπορείς να χρησιμοποιήσεις pattern matching για να ψάξεις για όλες με μία κλήση της Matches, π.χ. Regex.Matches(input, "Word1|Word2|Word3").

Μπορείς να φτιάξεις ένα function το οποίο θα φτιάχνει ένα pattern ενώνοντας όλες τις λέξεις με διαχωριστικό το '|' και θα επιστρέφει τα αποτελέσματα όπως παρακάτω:

    Function SearchWords(input As String, words As String()) As IEnumerable(Of Tuple(Of String, Integer, Integer))
        Dim pattern = String.Join("|", words)
        Dim matches = Regex.Matches(input, pattern)
        Dim indexes = From m As Match In matches
                      Select Tuple.Create(m.Value, m.Index, m.Length)
        Return indexes
    End Function

Εδώ χρησιμοποιώ και λίγο LINQ για να επιστρέψω τα αποτελέσματα που θέλω χωρίς να φτιάξω ξεχωριστή κλάση

Μετά μπορώ άνετα να κάνω αναζήτηση με μία μόνο κλήση, για όλες τις λέξεις όπως παρακάτω:

        Dim text = "This is some text I want to search. Try to find some words here"
        Dim search As String() = {"some", "to"}

        Dim results = SearchWords(text, search)

        For Each result In results
            Console.WriteLine("Found {0} at {1}:{2}", result.Item1, result.Item2, result.Item3)
        Next
        Console.ReadKey()

Απ: Πρόβλημα με Async σε richTextBox

Markos — Fri, 24 Feb 2012 21:33:14 GMT

Μισό λεπτό για να καταλάβω... Κάνεις σύγκριση κατανομών; Αν ναι, δώσε ένα παράδειγμα με το είδος των αναζητήσεων που κάνεις. Πιθανόν το να σου έρχονται τα αποτελέσματα σε λίστα να είναι προτιμότερο από να χρωματίζεις το RTB.

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 21:07:54 GMT

Markos:
Και θα συνεχίσεις να έχεις πρόβλημα όσο αρνείσαι να κατανοήσεις ότι το πρόβλημά σου είναι πρωτίστως αλγοριθμικό και δευτερευόντως (αλλά ΠΟΛΥ δευτερευόντως) προγραμματιστικό. Ο λόγος είναι απλός: Σε προβλήματα μεταθέσεων (permutations) και συνδυασμών (combinations) ΔΕΝ υπάρχει worst case scenario.

Πάρε για παράδειγμα ένα string permutation πρόβλημα με 15 strings {s1, s2,..., s15}. Το πλήθος των permutations είναι 1307674368000. Αν θέλεις να κάνεις search για να βρεις τα permutations με γενικό σχήμα {*,s4,s12} είναι ΠΟΛΥ προτιμότερο να τα παράγεις από την αρχή. Στην ουσία αυτό που πρέπει να κάνεις είναι να ανάγεις το search σε permutation πρόβλημα δεκατριών strings και να προσθέσεις στο τέλος τα s4 και s12. Στο πρόβλημα των 13, το σύνολο των permutations είναι 6227020800 (το 0,48% του συνόλου του αρχικού προβλήματος των 15). Το search, λοιπόν, στο αρχικό σύνολο είναι ασύμφορο. Επιπλέον, είναι εντελώς παράλογο να κρατάς τόσα πολλά δεδομένα στη μνήμη. Και το παράδειγμα που ανέφερα είναι πολύ απλό. Σε πιο σύνθετες αναζητήσεις, η προσέγγιση πρέπει να είναι πιο εκλεπτυσμένη από ένα μετωπικό brute force, αλλιώς δεν θα τελειώσεις ποτέ!

Τα permutations δεν γίνονται σε αυτό τον αλγόριθμο! Ότι ήταν να γίνει με permutation έχει ήδη γίνει. Έχει περάσει στην R (γλώσσα προγραμματισμού), έχω ήδη πάρει πίσω αποτελέσματα για kolmogorov και τα λοιπά... είναι άσχετο αυτό.

Τα permutations γίνονται πολύ γρήγορα. Πρόβλημα έχω στο να χρωματίσω το κείμενο...

Markos:
Τώρα, το προγραμματιστικό σου πρόβλημα ακούει στο όνομα RTB. Ό,τι χειρότερο. Άκουσε τον Παναγιώτη και ακολούθησε τη συμβουλή του και βάζε τα permutations σε λίστα. Διαφορετικά, καμία τεχνική threading δεν πρόκειται να σε σώσει. Αν θέλεις, για να καταλάβουμε κι εμείς καλύτερα τι θέλεις να κάνεις, δώσε μας ένα παράδειγμα με τα permutations που παράγεις και τις αναζητήσεις που κάνεις.

Επίσης, έχω ακολουθήσει αυτό που μου είπαν, και δεν κάνω search πάνω στο κείμενο του rtb, αλλά σε string. Κοίτα τον τελευταίο κώδικα που έγραψα και θα το δεις.

Υ.Γ. Nikos123 μην μπερδευτείς με το μήνυμα αυτό που έγραψα. Οι ερωτήσεις που έχω στο προηγούμενο μήνυμα ισχύουν ακόμα.

Ευχαριστώ πολύ και τους 2 για την προσπάθειά σας να με βοηθήσετε :)

Απ: Πρόβλημα με Async σε richTextBox

Markos — Fri, 24 Feb 2012 20:59:51 GMT

AlKiS:
nikos123:
Εσένα κάνει αυτά που θες (και σχετικά γρήγορα) το πρόγραμμα;
Ναι, πολύ πιο γρήγορα απότι πριν. Αλλά για Β>400 κολλάει πολύ και πάλι. Γιαυτό πρέπει να το κάνω σε Async.

Και θα συνεχίσεις να έχεις πρόβλημα όσο αρνείσαι να κατανοήσεις ότι το πρόβλημά σου είναι πρωτίστως αλγοριθμικό και δευτερευόντως (αλλά ΠΟΛΥ δευτερευόντως) προγραμματιστικό. Ο λόγος είναι απλός: Σε προβλήματα μεταθέσεων (permutations) και συνδυασμών (combinations) ΔΕΝ υπάρχει worst case scenario.

Πάρε για παράδειγμα ένα string permutation πρόβλημα με 15 strings {s1, s2,..., s15}. Το πλήθος των permutations είναι 1307674368000. Αν θέλεις να κάνεις search για να βρεις τα permutations με γενικό σχήμα {*,s4,s12} είναι ΠΟΛΥ προτιμότερο να τα παράγεις από την αρχή. Στην ουσία αυτό που πρέπει να κάνεις είναι να ανάγεις το search σε permutation πρόβλημα δεκατριών strings και να προσθέσεις στο τέλος τα s4 και s12. Στο πρόβλημα των 13, το σύνολο των permutations είναι 6227020800 (το 0,48% του συνόλου του αρχικού προβλήματος των 15). Το search, λοιπόν, στο αρχικό σύνολο είναι ασύμφορο. Επιπλέον, είναι εντελώς παράλογο να κρατάς τόσα πολλά δεδομένα στη μνήμη. Και το παράδειγμα που ανέφερα είναι πολύ απλό. Σε πιο σύνθετες αναζητήσεις, η προσέγγιση πρέπει να είναι πιο εκλεπτυσμένη από ένα μετωπικό brute force, αλλιώς δεν θα τελειώσεις ποτέ!

Τώρα, το προγραμματιστικό σου πρόβλημα ακούει στο όνομα RTB. Ό,τι χειρότερο. Άκουσε τον Παναγιώτη και ακολούθησε τη συμβουλή του και βάζε τα permutations σε λίστα. Διαφορετικά, καμία τεχνική threading δεν πρόκειται να σε σώσει. Αν θέλεις, για να καταλάβουμε κι εμείς καλύτερα τι θέλεις να κάνεις, δώσε μας ένα παράδειγμα με τα permutations που παράγεις και τις αναζητήσεις που κάνεις.

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 19:49:08 GMT

nikos123:
Εσένα κάνει αυτά που θες (και σχετικά γρήγορα) το πρόγραμμα;

Ναι, πολύ πιο γρήγορα απότι πριν. Αλλά για Β>400 κολλάει πολύ και πάλι. Γιαυτό πρέπει να το κάνω σε Async.

nikos123:
Όσο για το WorkSpaceFont μην το δημιουργείς και το καταστρέφεις σε κάθε κλήση της CororiseRTB .
Δήλωσε το ως member στη φόρμα, αρχικοποιήσε το μια φορά στο constructor (μετά το InitialiseComponent) και μην το κάνεις Dispose μέσα στην ColoriseRTB.

Εννοείς να το βάλω ByVal? Το έχω ήδη κάνει..

"Αρχικοποίησε το" τι εννοείς?

Δεν έχει πουθενά " InitialiseComponent"... άρα τι κάνω?

Που να το κάνω dispose ???

let me pinpoint the fact that καλώ αυτή τη συνάρτηση και σε άλλες μεριές.

nikos123:
Επίσης προσπάθησε να μην καλείς με πολλές παραμέτρους τις συναρτήσεις (5 στην ColoriseRTB , 2 μόνο για το Font).

Όλες οι παράμετροι είναι valid. Δεν θα μπορούσα να την καλέσω με λιγότερες... αν μπορείς να μου την φτιάξεις αλλιώς, τότε πλζ, κάντο για να το δω.

Note: Στις άλλες μεριές που την καλώ, χρειάζεται να βάψω και το background color, όπως και το "bold" αλλάζει σε "underline". δλδ μπορεί στο rtbWorkSpace_TextChanged να τα βλέπεις όλα ίδια, αλλά δεν είναι στις επόμενες.

Γιαυτό δεν πιστεύω ότι μπορεί να γίνει με λιγότερες παραμέτρους.

nikos123:
To async απ' όσο ξέρω δεν κάνει κάτι αφού δεν έχεις await.

Σωστό είναι αυτό που λες. Αλλά αφού στο τέλος θα την κάνουμε async, δεν έχει νοήμα να το βγάλω τώρα για να το ξαναβάλω μετά.

nikos123:
Ο έλεγχος matches.Count >0 δεν χρειάζεται

Αχά, έχει απο μόνο του έλεγχο? Καλό :)

Το έβγαλα λοιπών.

Φίλε μου Νίκο σε ευχαριστώ πολύ για την βοήθειά σου.

Όταν έχεις χρόνο, σκέψου πως μπορούμε να το κάνουμε και async... είναι πολύ σημαντικό αυτό.

Απ: Πρόβλημα με Async σε richTextBox

nikos123 — Fri, 24 Feb 2012 18:19:17 GMT

Εσένα κάνει αυτά που θες (και σχετικά γρήγορα) το πρόγραμμα;

Όσο για το WorkSpaceFont μην το δημιουργείς και το καταστρέφεις σε κάθε κλήση της CororiseRTB .

Δήλωσε το ως member στη φόρμα, αρχικοποιήσε το μια φορά στο constructor (μετά το InitialiseComponent) και μην το κάνεις Dispose μέσα στην ColoriseRTB.

Επίσης προσπάθησε να μην καλείς με πολλές παραμέτρους τις συναρτήσεις (5 στην ColoriseRTB , 2 μόνο για το Font).

To async απ' όσο ξέρω δεν κάνει κάτι αφού δεν έχεις await.

Ο έλεγχος matches.Count >0 δεν χρειάζεται

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 07:35:55 GMT

nikos123:
To MatchCollection αποτελείται από Match αντικείμενα. Αν η λέξη που ψάχνεις βρίσκεται σε 5 φορές μέσα στο κείμενο, το MatchCollection θα περιέχει 5 Match.
Το Match έχει ένα property Index με την θέση της λέξης.

Π.χ. 5 φορές το "ABC"
MatchCollection matches = Regex.Matches("asdaABCdsadaABCertyuuiaABChjghjABChgjhgjhjABCsdfsdfs", "ABC"); foreach(Match item in matches) { rtb.SelectionStart = item.Index; rtb.SelectionLength = item.Length;
rtb.SelectionFont = boldFont;
}
Τα Font πρέπει να γίνονται Dispose() για να διαγραφούν.
Φτιάξε ένα Font member και να χρησιμοποιείς πάντα αυτό χωρίς να δημιουργείς νέα.
        Font boldFont;
        public Form1()
        {
            InitializeComponent();
            boldFont = new Font(rtb.Font, FontStyle.Bold);
        }

Ok, ακολούθησα τα guidelines και έγραψα αυτό:

    Public Sub ColouriseRTB(ByVal rtb As RichTextBox, ByVal ColourizeableText As String, ByVal rtbFontStyle As FontStyle, ByVal rtbColour As Color, ByVal rtbBackColour As Color, Optional ByVal iLengthDeviation As Integer = 0)
        Dim rtbMatches As MatchCollection
        Dim rtbText As String = rtb.Text
        Dim WorkSpacefont As Font = New Font(rtb.Font, rtbFontStyle)

        rtbMatches = Regex.Matches(rtbText, ColourizeableText, RegexOptions.None)
        If rtbMatches.Count > 0 Then
            For Each item As Match In rtbMatches
                rtb.SelectionStart = item.Index
                rtb.SelectionLength = item.Length + iLengthDeviation
                rtb.SelectionFont = WorkSpacefont
                rtb.SelectionColor = rtbColour
                rtb.SelectionBackColor = rtbBackColour
            Next
        End If
        WorkSpacefont.Dispose()

    End Sub

    Private Async Sub rtbWorkSpace_TextChanged(sender As System.Object, e As System.EventArgs) Handles rtbWorkgroup.TextChanged
        If rtbWorkgroup.Text <> "" Then
            mniExportImWindow.Enabled = True
            mniExportEverything.Enabled = True

            If DatasetLength = 2 Then
                Call Controls2DBStatusNormal()
            Else
                Call ControlsManyDBStatusNormal()
            End If

            If showOutputColoured = True Then
                If (CombinationsCount * T_Repetition * n_NumberOfErrors) < (3 * 200 * 100) Then 'So as not to crush UI
                    ColouriseRTB(rtbWorkgroup, (txtLanguage.Lines(71)), FontStyle.Bold, WorkSpaceMainVariablesColours, DefaultBackColor) 'Permutation
                End If

                ColouriseRTB(rtbWorkgroup, txtLanguage.Lines(66), FontStyle.Bold, WorkSpaceMainVariablesColours, DefaultBackColor) 'Permutations

                ColouriseRTB(rtbWorkgroup, txtLanguage.Lines(67), FontStyle.Bold, WorkSpaceMainVariablesColours, DefaultBackColor) 'Max Vertical Deviation

                ColouriseRTB(rtbWorkgroup, txtLanguage.Lines(58), FontStyle.Bold, WorkSpaceMainVariablesColours, DefaultBackColor) 'KS p-value REC

            End If

        Else
            Call ControlsStatusDisableAll()

        End If
    End Sub

Είναι εντάξει τώρα?

Απ: Πρόβλημα με Async σε richTextBox

Markos — Fri, 24 Feb 2012 03:01:47 GMT

Αν γνωρίζεις ακριβώς ποιo(-α) είναι to permutation που ζητάς, δε χρειάζεται να παράγεις όλο το σύνολο των permutations για να το βρεις. Ρίξε μια μιατιά στο άρθρο String Permutations (έχει και κώδικα που μπορείς να κάνεις download). Πιθανόν οι τεχνικές που αναφέρονται εκεί σε βοηθήσουν να βελτιστοποιήσεις τον κώδικά σου. Επίσης βρήκα και αυτό το link (TextMechanic). Είναι λίγο off topic, αλλά μπορεί να σου δώσει ιδέες για προσθέσεις λειτουργικότητα στην εφαρμογή σου.

[Προσθήκη]

Μπορεί να φανεί αιρετικό αυτό που θα πω, αλλά διαβάζοντας το άρθρο μου δημιουργήθηκε η εντύπωση ότι με κάθε νέο search ίσως είναι πιο γρήγορο να "ξαναπαράγεις" τα permutations και να "χρωματίζεις" εκείνα που σ' ενδιαφέρουν καθώς κάνεις append το string, παρά να ψάχνεις ξανά και ξανά ένα πιθανώς χαοτικό σε μέγεθος string. Οι υπόλοιποι, τι λέτε επ' αυτού;

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 02:17:56 GMT

Ευχαριστώ πολύ,

όταν βρω το χρόνο να συνεχίσω το πρόγραμμα θα το δοκιμάσω αμέσως και θα απαντήσω σε αυτό το thread.

thanks :)

Απ: Πρόβλημα με Async σε richTextBox

nikos123 — Fri, 24 Feb 2012 02:09:00 GMT

To MatchCollection αποτελείται από Match αντικείμενα. Αν η λέξη που ψάχνεις βρίσκεται σε 5 φορές μέσα στο κείμενο, το MatchCollection θα περιέχει 5 Match.

Το Match έχει ένα property Index με την θέση της λέξης.

Π.χ. 5 φορές το "ABC"

           MatchCollection matches = Regex.Matches("asdaABCdsadaABCertyuuiaABChjghjABChgjhgjhjABCsdfsdfs", "ABC");
            foreach(Match item in matches)
            {
                rtb.SelectionStart = item.Index; 
                rtb.SelectionLength = item.Length;

                rtb.SelectionFont = boldFont;

Τα Font πρέπει να γίνονται Dispose() για να διαγραφούν.

Φτιάξε ένα Font member και να χρησιμοποιείς πάντα αυτό χωρίς να δημιουργείς νέα.

        Font boldFont;
        public Form1()
        {
            InitializeComponent();
            boldFont = new Font(rtb.Font, FontStyle.Bold);
        }

Απ: Πρόβλημα με Async σε richTextBox

AlKiS — Fri, 24 Feb 2012 00:58:14 GMT

Οι πράξεις γίνονται σε μεταβλητές Double()().

800 γραμμές είναι του dataset. Το κείμενο αυτό δείχνει όλα τα permutations που έγιναν, τα οποία είναι 800 (γραμμές) * (Β φορές το οποίο διαλέγει ο χρήστης) * Το διωνυμικό συντελεστή των στηλών ανά 2, άρα πες *16 = 12787200 σειρές ΜΟΝΟ τα permutations.

(και αυτό ΔΕΝ είναι ούτε καν κοντά στο worst case scenario)

Αν σκεφτείς και τα υπόλοιπα δεδομένα που περιέχει (Maximum Vertical Deviation, ks p-value, texts..) τότε χαθήκαμε.

Αλλά ξεφύγαμε απο το point όμως.

Crap, δεν ξέρω το List(of T)

anyway, θα το κοιτάξω τώρα.

Αν θες απάντησέ μου στις ερωτήσεις που έκανα πάνω στο προηγούμενο πόστ σου, και ειδικά αυτή για το "Regex.Matches"

Aν μπορείς να μου γράψεις και ένα μικρό παραδειγματάκι χρησιμοποιώντας αυτό για να το καταλάβω καλύτερα θα ήταν τέλεια.

Ευχαριστώ για τη βοήθεια

Απ: Πρόβλημα με Async σε richTextBox

Παναγιώτης Καναβός — Fri, 24 Feb 2012 00:31:42 GMT

Permutations??? Αν θέλεις να κάνεις υπολογισμούς, η χρήση του κειμένου ενός textbox είναι ο χειρότερος δυνατός τρόπος. Αν θέλεις να "σκαλίσεις" τα δεδομένα από κάποιο κείμενο, φόρτωσε τα, διάβασε τα γραμμή-γραμμή και γέμισε ένα πίνακα ή μία λίστα (εννοώ το κλασσικό List, ή όποιο άλλο collection σε βολεύει) και μετά κάνε τους υπολογισμούς που θέλεις.

800 γραμμές είναι μηδαμινές ως όγκος δεδομένων, όσο μακρυές και αν είναι. Όσο για τα Β και τις στήλες ... δεν καταλαβαίνω καν τί εννοείς. Ίσως να είναι κάτι που έχεις συζητήσει σε άλλο, άσχετο post.