Πρώτα Βήματα - Web Development

Απ: Tutorial με Custom VB Class

neoklis — Sun, 27 Feb 2011 18:11:25 GMT

Για κάποιον λόγο δεν το βλέπω στα pm. Ευτυχώς όμως ήρθε στο email μου. Σε ευχαριστώ για την βοήθεια σου...

Απ: Tutorial με Custom VB Class

Libra Storm — Sun, 27 Feb 2011 03:06:10 GMT

Σου έστειλα τον κώδικα γιά Visual basic 2008. Γιά κάποιον λόγο θέλει έγκριση, μάλλον δεν θα στάλθηκε σωστά. Θα σου το στείλω και με PM.

Απ: Tutorial με Custom VB Class

Libra Storm — Sun, 27 Feb 2011 03:04:08 GMT

' Σε Visual Basic 2008

Option Strict On

Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
#If DEBUG Then
        ' Δεν χρειάζεται να βάζουμε πάντα breakpoints στο .net από το IDE
        ' γίνεται και από κώδικα
        'If Debugger.IsAttached Then Debugger.Break()
#End If

        Dim a As New PersonWithModuleInsert("Dimitris")
        Dim b As New PersonWithSharedInsert("Giorgos", 18) With {.Telephone = "(+30) 210 78459345"} ' ή αλλιώς b.Telephone = "(+30) 210 78459345"
        Dim c As New PersonWithInstanceInsert("Panagiotis", 22)

        ' κάνε nouse Hover (όταν κάνεις debug) πάνω από κάθε object (a, b ,c) γιά να δεις τις επιπλέον πληροφορίες που προσθέσαμε.

#If DEBUG Then
        Debug.WriteLine(CType(a, String))
        Debug.WriteLine(a.ToString())
#End If
        ' Που είναι το module που κάνει insert το Person στην βάση; Ουφ το βρήκα επιτέλους :)
        ModPersonTools.Insert(a)

        ' Αντί να ψάχνεις το Module με τις συναρτήσεις γιά το κάθε Person το έχεις έτοιμο από το class Person_WithSharedInsert
        PersonWithSharedInsert.Insert(b)

        ' Τι;, κάθε φορά θα "σηκώνω" ένα function στην μνήμη (μετά από κάθε new Instance) γιά να κάνει Insert; γιατί;
        c.Insert()
    End Sub
End Class ' Form1



Public Enum Sex
    Male
    Female
    Unknown
End Enum ' Sex



Public MustInherit Class Human
    Private _Age As Integer
    Public Property Age() As Integer
        Get
            Return _Age
        End Get
        Set(ByVal value As Integer)
            _Age = value
        End Set
    End Property

    Private _Sex As Sex = Sex.Unknown
    Public Property Sex() As Sex
        Get
            Return _Sex
        End Get
        Set(ByVal value As Sex)
            _Sex = value
        End Set
    End Property


End Class ' Human



Public MustInherit Class PersonBase
    Inherits Human

#Region "public:"
    Private _Name As String
    Public Property Name() As String
        Get
            Return _Name
        End Get
        Set(ByVal value As String)
            _Name = value
        End Set
    End Property

    Private _Telephone As String
    Public Property Telephone() As String
        Get
            Return _Telephone
        End Get
        Set(ByVal value As String)
            _Telephone = value
        End Set
    End Property

    Public Shared Narrowing Operator CType(ByVal person As PersonBase) As String
        Return PersonBase._Info(person)
    End Operator

    ' Αυτό το function είναι κληρονομημένο από το Object.
    ' Όταν κάνεις debug θα δεις επίσης ότι σου δίνει και άλλες πληροφορίες που κάνουν
    ' την δουλεία σου ευκολότερη χωρίς να χρειάζεται να κάνεις expand το κάθε person class 
    ' όταν κάνεις mouse hover
    Public Overrides Function ToString() As String
        Return "Type Info: " & MyBase.ToString() & " " & PersonBase._Info(Me)
    End Function

    Public ReadOnly Property Identity() As String
        Get
            Return _Identity
        End Get
    End Property
#End Region



#Region "protected:"
    Protected Sub New(ByVal name As String)
        Me._CommonConstructor(name)
    End Sub

    Protected Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.Age = age

        Me._CommonConstructor(name)
    End Sub
#End Region



#Region "private:"
    Private Sub _CommonConstructor(ByVal Name As String)
        Me._Name = Name

        _ID += 1I
        Me._Identity = _PREFIX & _ID.ToString(System.Globalization.CultureInfo.InvariantCulture)
    End Sub

    Private Const _PREFIX As String = "PERSON_"
    Private _Identity As String = String.Empty

    ' Δοκίμασε να βγάλεις το Shared
    ' τότε Όλα τα Objects θα έχουν ID 0 :(
    Private Shared _ID As Integer = 0

    Private Shared Function _Info(ByVal person As PersonBase) As String
        Dim sb As New System.Text.StringBuilder
        Dim sInfo As String = Nothing

        sb.Append("ID: ").Append(person.Identity)
        sb.Append(", Name: ").Append(person.Name)
        sb.Append(", Sex: ").Append(person.Sex.ToString)
        sb.Append(", Age: ").Append(person.Age)
        sb.Append(", Telephone: ").Append(person.Telephone)

        sInfo = sb.ToString
        sb.Length = 0
        sb = Nothing

        Return sInfo
    End Function
#End Region

End Class ' PersonBase



Public Class PersonWithModuleInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

End Class



' Γιατί να φτιάχνουμε modules
' που φορτώνονται στην μνήμη χωρίς να χρησιμοποιούνται;
Public Module ModPersonTools
    Public Function Insert(ByVal thePerson As PersonBase) As Integer
        ' TODO insert to DB
        Return 1
    End Function

End Module ' ModPersonTools



' Αυτός ο τρόπος είναι κατά την γνώμη μου ο καλύτερος 
Public Class PersonWithSharedInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Shared Function Insert(ByVal thePerson As PersonBase) As Integer
        ' TODO insert to DB
        Return 1
    End Function

End Class ' PersonWithSharedInsert



Public Class PersonWithInstanceInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Function Insert() As Integer
        ' TODO insert to DB
        Return 1
    End Function
End Class ' PersonWithInstanceInsert

Απ: Tutorial με Custom VB Class

neoklis — Sat, 26 Feb 2011 17:41:08 GMT

το υποψιαζόμουνα ότι έχει να κάνει με το framework. Έχω εγκατεστημένο visual studio 2008, θα πρέπει να παίξει...

Απ: Tutorial με Custom VB Class

Libra Storm — Sat, 26 Feb 2011 06:44:43 GMT

Είναι Windows application γιά visual Studio 2010 με framework 4. Γιά αυτόν τον λόγο σου βγάζει αυτά τα μυνήματα λάθους. Παλιά στα properties έπρεπε πάντα να έχεις δηλωμένο ένα get και set, μιά private μεταβλητή γιά κάθε property είτε έγραφες κώδικα στα get και set είτε όχι.

Απ: Tutorial με Custom VB Class

neoklis — Fri, 25 Feb 2011 18:35:12 GMT

Πήγα να τρέξω τον κώδικα αλλά δυστυχώς χτυπάει errors.

Error 1 'Telephone' is not a member of 'WindowsApplication1.PersonWithSharedInsert'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 12 67 WindowsApplication1

Error 2 Property without a 'ReadOnly' or 'WriteOnly' specifier must provide both a 'Get' and a 'Set'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 43 21 WindowsApplication1

Error 3 Statement cannot appear within a property body. End of property assumed. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 44 5 WindowsApplication1

Error 4 Property missing 'End Property'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 44 5 WindowsApplication1

Error 5 Property without a 'ReadOnly' or 'WriteOnly' specifier must provide both a 'Get' and a 'Set'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 54 21 WindowsApplication1

Error 6 Statement cannot appear within a property body. End of property assumed. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 55 5 WindowsApplication1

Error 7 Statement cannot appear within a property body. End of property assumed. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 57 5 WindowsApplication1

Error 8 '_Name' is not a member of 'WindowsApplication1.PersonBase'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 94 9 WindowsApplication1

Error 9 'Sex' is not a member of 'WindowsApplication1.PersonBase'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 113 37 WindowsApplication1

Error 10 'Telephone' is not a member of 'WindowsApplication1.PersonBase'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 115 43 WindowsApplication1

Error 11 'Clear' is not a member of 'System.Text.StringBuilder'. C:\Users\neoklis\AppData\Local\Temporary Projects\WindowsApplication1\Form1.vb 118 9 WindowsApplication1

Απ: Tutorial με Custom VB Class

neoklis — Fri, 25 Feb 2011 06:30:34 GMT

Libra Storm:
Αν θέλεις τρέξε τον παρακάτω κώδικα που μπορεί να σε βοηθήσει στην κατανόηση του Shared vs module. Χρησιμοποιώ επίσης και αρκετές ευκολίες του .Net που ίσως σε βοηθήσουν στο project σου.

Αν θελω...; Φυσικά και θέλω...!

Σε ευχαριστώ πολύ για τον κόπο που έκανες να μου παρουσιάσεις shared methods vs functions από modules. Τι να πω... και πάλι σε ευχαριστώ..

Απ: Tutorial με Custom VB Class

Libra Storm — Mon, 21 Feb 2011 08:01:25 GMT

Μπορείς να βγάλεις το Shared function InsertPerson από το class και νά το βάλεις σε ένα module πχ modPerson (αφαιρώντας το Shared) και να το καλείς από εκεί (modPerson.InsertPerson).

Αντί όμως να φτιάχνεις modules (κακή κληρονομιά από την VB6) και να βάζεις εκεί τις συναρτήσεις που θέλεις, (στην ουσία σε έναν κουβά) το .NET σου επιτρέπει να ομαδοποιείς τις συναρτήσεις που αφορούν το κάθε αντικείμενο μέσα στο ίδιο το class (σαν Shared) οι οποίες (σε γενικές γραμμές) κάνουν το ίδιο πράγμα και διευκολύνουν εσένα και οποιονδήποτε άλλον που γράφει κώδικα στο να μήν ψάχνει μέσα σε modules που δυστυχώς τρώνε μνήμη είτε χρησιμοποιούνται είτε όχι.

Τα shared methods και τα functions από modules δεν χρειάζονται new γιά να κληθούν και γιά αυτόν τον λόγο αντί να γράφεις Dim a as new Person a.InsertPesron λές Person.InsertPerson αφού το InsertPerson είναι μία συνάρτηση που δεν χρειάζεται Instance του class (Person Object) γιά να κληθεί.

Θα μπορούσες φυσικά να φτιάξεις στην Class Person ενα method InsertPerson (χωρίς Shared) αλλά έτσι με κάθε new θα γεμίζεις την μνήμη με άχρηστα functions τα οποία δεν χρειάζεται να είναι μοναδικά ανά instance αλλά κοινά σε όλα τα Person.

Αν θέλεις τρέξε τον παρακάτω κώδικα που μπορεί να σε βοηθήσει στην κατανόηση του Shared vs module. Χρησιμοποιώ επίσης και αρκετές ευκολίες του .Net που ίσως σε βοηθήσουν στο project σου.

Option Strict On

Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
#If DEBUG Then
        ' Δεν χρειάζεται να βάζουμε πάντα breakpoints στο .net από το IDE
        ' γίνεται και από κώδικα
        If Debugger.IsAttached Then Debugger.Break()
#End If

        Dim a As New PersonWithModuleInsert("Dimitris")
        Dim b As New PersonWithSharedInsert("Giorgos", 18) With {.Telephone = "(+30) 210 78459345"} ' ή αλλιώς b.Telephone = "(+30) 210 78459345"
        Dim c As New PersonWithInstanceInsert("Panagiotis", 22)

        ' κάνε nouse Hover (όταν κάνεις debug) πάνω από κάθε object (a, b ,c) γιά να δεις τις επιπλέον πληροφορίες που προσθέσαμε.

#If DEBUG Then
        Debug.WriteLine(CType(a, String))
        Debug.WriteLine(a.ToString())
#End If
        ' Που είναι το module που κάνει insert το Person στην βάση; Ουφ το βρήκα επιτέλους :)
        ModPersonTools.Insert(a)

        ' Αντί να ψάχνεις το Module με τις συναρτήσεις γιά το κάθε Person το έχεις έτοιμο από το class Person_WithSharedInsert
        PersonWithSharedInsert.Insert(b)

        ' Τι;, κάθε φορά θα "σηκώνω" ένα function στην μνήμη (μετά από κάθε new Instance) γιά να κάνει Insert; γιατί;
        c.Insert()
    End Sub
End Class ' Form1



Public Enum Sex
    Male
    Female
    Unknown
End Enum ' Sex



Public MustInherit Class Human
    Public Property Age As Integer
    Public Property Sex As Sex = Sex.Unknown

End Class ' Human



Public MustInherit Class PersonBase
    Inherits Human

#Region "public:"
    Public Property Name As String
    Public Property Telephone As String

    Public Shared Narrowing Operator CType(ByVal person As PersonBase) As String
        Return PersonBase._Info(person)
    End Operator

    ' Αυτό το function είναι κληρονομημένο από το Object.
    ' Όταν κάνεις debug θα δεις επίσης ότι σου δίνει και άλλες πληροφορίες που κάνουν
    ' την δουλεία σου ευκολότερη χωρίς να χρειάζεται να κάνεις expand το κάθε person class 
    ' όταν κάνεις mouse hover
    Public Overrides Function ToString() As String
        Return "Type Info: " & MyBase.ToString() & " " & PersonBase._Info(Me)
    End Function

    Public ReadOnly Property Identity As String
        Get
            Return _Identity
        End Get
    End Property
#End Region



#Region "protected:"
    Protected Sub New(ByVal name As String)
        Me._CommonConstructor(name)
    End Sub

    Protected Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.Age = age

        Me._CommonConstructor(name)
    End Sub
#End Region



#Region "private:"
    Private Sub _CommonConstructor(ByVal Name As String)
        Me._Name = Name

        _ID += 1I
        Me._Identity = _PREFIX & _ID.ToString(System.Globalization.CultureInfo.InvariantCulture)
    End Sub

    Private Const _PREFIX As String = "PERSON_"
    Private _Identity As String = String.Empty

    ' Δοκίμασε να βγάλεις το Shared
    ' τότε Όλα τα Objects θα έχουν ID 0 :(
    Private Shared _ID As Integer = 0

    Private Shared Function _Info(ByVal person As PersonBase) As String
        Dim sb As New System.Text.StringBuilder
        Dim sInfo As String = Nothing

        sb.Append("ID: ").Append(person.Identity)
        sb.Append(", Name: ").Append(person.Name)
        sb.Append(", Sex: ").Append(person.Sex.ToString)
        sb.Append(", Age: ").Append(person.Age)
        sb.Append(", Telephone: ").Append(person.Telephone)

        sInfo = sb.ToString
        sb.Clear()
        sb = Nothing

        Return sInfo
    End Function
#End Region

End Class ' PersonBase



Public Class PersonWithModuleInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

End Class



' Γιατί να φτιάχνουμε modules
' που φορτώνονται στην μνήμη χωρίς να χρησιμοποιούνται;
Public Module ModPersonTools
    Public Function Insert(ByVal thePerson As PersonBase) As Integer
        ' TODO insert to DB
        Return 1
    End Function

End Module ' ModPersonTools



' Αυτός ο τρόπος είναι κατά την γνώμη μου ο καλύτερος 
Public Class PersonWithSharedInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Shared Function Insert(ByVal thePerson As PersonBase) As Integer
        ' TODO insert to DB
        Return 1
    End Function

End Class ' PersonWithSharedInsert



Public Class PersonWithInstanceInsert
    Inherits PersonBase

    Public Sub New(ByVal name As String)
        MyBase.new(name)
    End Sub

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Function Insert() As Integer
        ' TODO insert to DB
        Return 1
    End Function
End Class ' PersonWithInstanceInsert

Απ: Tutorial με Custom VB Class

dimos.homatas — Fri, 18 Feb 2011 20:11:33 GMT

Το λέω με το σκεπτικό ότι για τον Νεοκλή δεν έχει σημασία, εννοώντας ότι καλό είναι να ασχοληθεί με τον OOP και όχι με την έννοια "custom class", μιας και εάν μάθει τα βασικά του αντικειμενοστρεφούς, θα υπερκαλυφθεί στο ερώτημά του. Απλά δεν είναι short term.

Απ: Tutorial με Custom VB Class

Panagiotis Kefalidis — Fri, 18 Feb 2011 19:55:33 GMT

Δεν είναι έτσι ακριβώς.. μια κλάση δεν σημαινεί αναγκαστικά ότι θα γίνει και αντικείμενο.. αντικείμενα έχεις μετά το instantiation μιας κλάσης (όχι απαραίτητα, αλλά εδώ μιλάμε για basic, let's stick with that). Class είναι το blueprint ενός πχ σπιτιού αλλά το σπίτι που προκύπτει απο το blueprint είναι το αντικείμενο.

Απ: Tutorial με Custom VB Class

dimos.homatas — Fri, 18 Feb 2011 09:20:36 GMT

Είναι το ίδιο πράγμα, κλάση=αντικείμενο. Είναι η εξέλιξη των σύνθετων δομών δεδομένων.

Πχ μπορείς να φτιάξεις αντικείμενο "πελάτης", "προμηθευτής", "προϊόν" κλπ.

Απ: Tutorial με Custom VB Class

neoklis — Fri, 18 Feb 2011 02:40:17 GMT

Δήμο, υπήρχε θέμα με το connectionstring, το διόρθωσα και παίζει μια χαρά.

dimos.homatas:
Θεωρώ ότι θα ήταν καλύτερο να ψάξεις "objects in vb" στο google, παρά το custom classes. Μάθε λίγο για τα βασικά του αντικειμενοστρεφούς προγραμματισμού στην vb και μετά θα σου έρθουν πιο καλά.

Αυτό που μου λες, αν κατάλαβα καλά, είναι να μάθω περί αντικειμενοστρεφούς προγραμματισμού πρώτα και μετά να προχωρήσω σε custom classes;

Απ: Tutorial με Custom VB Class

dimos.homatas — Fri, 18 Feb 2011 01:02:45 GMT

Θα ρίξω πάντως και μια ματιά στο tutorial και θα σου πω.

Απ: Tutorial με Custom VB Class

neoklis — Fri, 18 Feb 2011 00:06:53 GMT

Πρώτα να σε ευχαριστήσω για την βοήθεια σου. Έχω SQL Server 2008 Express εγκατεστημένο, και αυτό που κατέβασα τα είχε όλα (ΒΔ, SP), το όνομα της βάσης είναι σωστό(mdf και όχι mdb). Αυτό που θέλω να κάνω είναι να αποθηκεύονται τα labeltext data στον SQL. Αργότερα να μπορώ να διαβάσω τα data από τον SQL και να τα εμφανίσω σε labes. Σίγουρα υπάρχουν αρκετοί τρόποι για να γίνει αυτό, απλά θεώρησα ότι μια custom class είναι αυτό που χρειάζομαι. Εσύ όμως μου λες να ρίξω μια ματιά για "objects in vb". Θα το κοιτάξω και αν είναι τα ξαναλέμε.

Απ: Tutorial με Custom VB Class

dimos.homatas — Thu, 17 Feb 2011 23:49:15 GMT

Για να στο είπε έτσι, πάει να πει ότι η μέθοδος InsertPerson είναι static, άρα μπορείς να την καλέσεις χωρίς να δώσεις instance στο αντικείμενο.

Έχεις sql server εγκατεστημένο; Το connection string είναι δικό σου ή είναι κατεβασμένο; Ψιλοgeneric μου φαίνεται (Database.mdb ? )

Χώρια που φωνάζει και stored procedures. Εσύ μόνο τον κώδικα κατέβασες ή έβαλες και ΒΔ;

Δεν πρόκειται να παίξει χωρίς την ΒΔ του πάντως.

Θεωρώ ότι θα ήταν καλύτερο να ψάξεις "objects in vb" στο google, παρά το custom classes. Μάθε λίγο για τα βασικά του αντικειμενοστρεφούς προγραμματισμού στην vb και μετά θα σου έρθουν πιο καλά.

Το θέμα της σύνδεσης με την βάση πάντως είναι άλλο καπέλο.